Dùng LaTeX tạo ra một file GIF

Tạo một file metapost đặt tên là dh9giay.mp
 

path hand[];
hand1 = origin .. (.257,1/50) .. (.377,1/60)
& (.377,1/60) {up} .. (.40,3/50)
.. (.60, 1/40) .. {right} (.75,0);
hand1 := (hand1 .. reverse hand1 reflectedabout(left,right)
.. cycle) scaled 50;
hand2 = origin .. (.60, 1/64) .. {right} (.925,0);
hand2 := (hand2 .. reverse hand2 reflectedabout(left,right)
.. cycle) scaled 50;
vardef htod(expr hours) = 30*((15-hours) mod 12) enddef;
vardef mtod(expr minutes) = 6*((75-minutes) mod 60) enddef;
vardef clock(expr hours, minutes) = image(
fill fullcircle scaled 100 withcolor 1/256(240, 240, 230);
draw fullcircle scaled 99 withcolor .8 white;
draw fullcircle scaled 100 withpen pencircle scaled 7/8;
for t=0 step 6 until 359:
draw ((48,0)--(49,0)) rotated t;
endfor
for t=0 step 30 until 359:
draw ((47,0)--(49,0)) rotated t withpen pencircle scaled 7/8;
endfor
for h=1 upto 12:
label(decimal h infont "bchr8r", (40,0) rotated htod(h));
endfor
pickup pencircle scaled 7/8;
filldraw hand1 rotated htod(hours+minutes/240) withcolor red;
filldraw hand2 rotated mtod(minutes/4) withcolor blue;
draw origin withpen pencircle scaled 5;
undraw origin withpen pencircle scaled 3;
)
enddef;
for i = 0 upto 240:
beginfig(i);
draw clock(9, i); % 9 giờ, i phút
endfig;
endfor
end


 

Biên dịch file dh9giay.mp ra 240 file pdf bởi lệnh
mptopdf dh9giay.mp
 

Soạn một file $\rm TeX$ như sau:
 

\multido{\n=0+1}{240}{\includegraphics[scale=2]{dh9giay-\n.pdf} \newpage }
\end{document}
 
Dùng $\rm Lua\LaTeX$ biên dịch thành một file pdf duy nhất tên là dh9giay.pdf

Dùng GIMP mở file dh9giay.pdf export to GIF thành file dh9giay.gif với tần số 15000 (mili giây).
 
Kết quả đồng hồ sẽ chạy bắt đầu vào lúc 9 giờ với kim giờ và kim phút sau mỗi 15 giây:
 

About TS. Nguyễn Thái Sơn

Nguyên trưởng Khoa Toán-Tin học ĐHSP TP HCM (1999-2009). Nguyên Giám đốc- Tổng biên tập NXB ĐHSP TP HCM (2009-2011). Nguyên Tổng thư ký Hội Toán học TP HCM (2008-2013).