Phép nghịch đảo và metapost (1)

 
Nếu $k>0$ thì đường tròn tâm $O$ bán kính $R=\sqrt{k}$ là tập hợp những điểm bất biến, ta gọi nó là đường tròn nghịch đảo.
 

Metapost cung cấp phép nghịch đảo cực $O$ và đường tròn bất biến tâm $O$ bán kính $R$.
 

Đoạn code metapost sau đây xác định một phép nghịch đảo cực $A(2;2)$ và đường tròn nghịch đảo có bán kinh $R=3$
 

\begin{mplibcode}
input geom2d;
beginfig(1);
A = Point(2,2);
C = Cercle(A,3);
trace C dashed evenly avecCrayon(0.8,Orange);
marque.rt "A";
B = Point(0,1); D = Inversion(B,C) ;
marque.ulft "B"; marque.ulft "D";
drawoptions(withcolor DarkRed);
AB = Segment(A,D);
trace(AB);
endfig;
\end{mplibcode}

Hình vẽ dưới đây minh họa cho đoạn code: phép nghịch đảo cực $A$ biến điểm $B$ thành điểm $D$, đường tròn nghịch đảo chấm chấm dashed evenly, màu cam (orange).
 

 

Trong phép nghịch đảo $\text{NĐ}(A,3^2)$ dưới đây ta xét đường thẳng d đi qua hai điểm $B_1(-4;1), B_2(1,0)$ (chú ý tọa độ trong metapost là dấy phẩy). Gọi Cd là ảnh của đường thẳng d qua phép nghịch đảo. Metaposst thực hiện phép biến hình như hình vẽ:
 

\begin{mplibcode}
input geom2d;
beginfig(1);
A = Point(2,2);
C = Cercle(A,3);
trace C dashed evenly avecCrayon(1,Blue);
marque.top "A";
B_1 = Point(-4,1); pointe B_1;
B_2 = Point(1,0); pointe B_2;
d = Droite(B_1,B_2);
trace d avecCrayon(1,DarkGreen);
Cd = Inversion(d,C);
trace Cd avecCrayon(2,Gray);
Fenetre(-5,-3,5,5);
endfig;
\end{mplibcode}

 

 

 

\begin{mplibcode}
input geom2d;
beginfig(1);
O = Point(0,0);
C = Cercle(O,4);
trace C avecCrayon(1,Orange);
marque.bot "O";
M = Point(8,1); N = Point(7.125,-7.5); pointe M;
d = Droite(M,N);
trace d avecCrayon(1,Magenta);
marque.rt "M";
Fenetre(-5,-5,9,10);
endfig;
\end{mplibcode}


Metapost thực hiện phép dựng hình như sau: (thầy Sơn giải thích ở dưới )
 

\begin{mplibcode}
input geom2d;
beginfig(1);
O = Point(0,0);
C = Cercle(O,4);
trace C avecCrayon(1,Orange);
marque.bot "O";
M = Point(8,1); N = Point(7.125,-7.5); pointe M;
d = Droite(M,N);
trace d avecCrayon(1,Magenta);
marque.rt "M";
AB=DroitePerpendiculaire(d,O); trace AB;
A = IntersectionDroiteCercle(AB,C,1); pointe A;marque.top "A";
B = IntersectionDroiteCercle(AB,C,2); pointe B;marque.urt "B";
At=DroitePerpendiculaire(AB,A); trace At avecCrayon(1,Blue);
Bu=DroitePerpendiculaire(AB,B); trace Bu avecCrayon(1,Red);
v = CercleD(O,M); P = IntersectionCercles(C,v); pointe P;marque.top "P";
W = CercleCP(M,P);
C_1 = Inversion(At,W); trace C_1 avecCrayon(2.5,Blue);
C_2 = Inversion(Bu,W); trace C_2 avecCrayon(2.5,Red);
Fenetre(-5,-5,9,10);
endfig;
\end{mplibcode}



.

Dựng hình:
 

1. Dựng đường kính $AB$ vuông góc với $d$ với câu lệnh metapost:

AB=DroitePerpendiculaire(d,O); trace AB;
A = IntersectionDroiteCercle(AB,C,1); pointe A;marque.top "A";
B = IntersectionDroiteCercle(AB,C,2); pointe B;marque.urt "B";
 
2. Dựng hai tiếp tuyến $At$ và $Bu$ của đường tròn $(O)$ vuông góc với $d$ với câu lệnh metapost:
 
At=DroitePerpendiculaire(AB,A); trace At avecCrayon(1,Blue);
Bu=DroitePerpendiculaire(AB,B); trace Bu avecCrayon(1,Red);
 
3. Xét phép nghịch đảo cực $M$ phương tích $MP^2$ (trong đó $P$ là tiếp điểm của một tiếp tuyến đi qua $M$). Đường tròn nghịch đảo chính là đường tròn tâm $M$ bán kính $MP$, câu lệnh metapost:
 


v = CercleD(O,M); P = IntersectionCercles(C,v); pointe P;marque.top "P";
W = CercleCP(M,P);
 

 
4. Phép nghịch đảo cực $M$ phương tích $MP^2$ sẽ biến hai đường thẳng $At, Bu$ thành hai đường tròn cần dựng, câu lệnh metapost:
 


C_1 = Inversion(At,W); trace C_1 avecCrayon(2.5,Blue);
C_2 = Inversion(Bu,W); trace C_2 avecCrayon(2.5,Red);

 
 
 

bt_nd1

About TS. Nguyễn Thái Sơn

Nguyên trưởng Khoa Toán-Tin học ĐHSP TP HCM (1999-2009). Nguyên Giám đốc- Tổng biên tập NXB ĐHSP TP HCM (2009-2011). Nguyên Tổng thư ký Hội Toán học TP HCM (2008-2013).